request-handler /temphist
    out-header default

    task-param action

    if-task "record"
        input-param temp
        run-query @db_utility = "insert into temps (temp, timest) values ('%s', current_timestamp)" : temp \
            affected-rows define rc error-text define er no-loop
        if (rc != 1) {
            @Could not insert temperature reading, error <<p-out er>>.
        } else {
            @Temperature reading stored.
        }
    else-task "list"
        run-query @db_utility = "select temp, timest from temps order by timest" output temp, timest
            @Date: <<query-result  timest>>
            @Temperature: <<query-result  temp>>
        end-query
    end-task
end-request-handler

request-handler /upload
   out-header default

   input-param filedesc      // file description from the upload form
   input-param file_filename // file name
   input-param file_location // the path to uploaded file
   input-param file_size     // size in bytes
   input-param file_ext      // the file extension

   @<h2>Uploading file</h2>

   // insert the information about the file into the database
   run-query @db_file_manager= \
        "insert into files (fileName, localPath, extension, description, fileSize) \
            values ('%s', '%s', '%s', '%s', '%s')" \
        input file_filename, file_location, file_ext, filedesc, file_size
   end-query

   @File <<p-web file_filename>> of size <<p-web file_size>> \
        is stored on server at <<p-web file_location>>. \
        File description is <<p-web filedesc>>.<hr/>
end-request-handler

request-handler /status
   silent-header
   out-header default
   input-param server
   input-param days

   // Create URL payload for remote server
   pf-out "/days/%s", days to define payload
   // Create a string describing the remote server with IP and port
   pf-out "%s:3800", server to define srv_location

   // Create a remote server connection
   new-server define srv location srv_location \
       method "GET" app-path "/server" \
       request-path "/remote_status" \
       url-payload payload \
       timeout 30

   // Call the remote server
   call-server srv
   // Get the results from remote server
   read-server srv data define dt
   // Print out the results
   @Output is: [<<p-out dt>>]
end-request-handler

#include <math.h>

int factorial(int num);

%% /using-c
    out-header default
    input-param inp
    int res = factorial (atoi(inp));
    @Factorial of <<p-out inp>> is <<p-num res>>!
    double sr = sqrt ((double)res);
    @And its square root is <<p-dbl sr>>!
%%

int factorial(int num)
{
    int res = 1;
    int i;
    for (i = 2; i <= num; i++) {
        res *= i;
    }
    return res;
}